[ivy-c] création du paquet et conflit sur /usr/lib64 (résolu)

[gael]

bonjour,

j'ai fait un PKGBUILD pour ivy-c mais lors de l'installation du paquet j'ai l'erreur

Code : Tout sélectionner

erreur : la validation de la transaction a échoué (conflit de fichiers)
ivy-c : /usr/lib64 est déjà présent dans le système de fichiers

voici le PKGBUILD

Code : Tout sélectionner

pkgname=ivy-c
pkgver=3.9.2
pkgrel=1
pkgdesc="ivy-c Library"
arch=('i686' 'x86_64')
url="http://www.eei.cena.fr/products/ivy/download/source.html"
license=('GPL3')
depends=('tcl')
makedepends=('cmake')
source=("http://www.eei.cena.fr/products/ivy/download/packages/${pkgname}-${pkgver}.tar.gz")
md5sums=('c105e1f42ad2020e6b7ae83709b073e7')
build() {
  cd "${srcdir}/${pkgname}-${pkgver}/src"
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}/src"
 make DESTDIR="${pkgdir}" install
}

merci pour vos conseils

[benjarobin]

Ceci devrait être mieux :

Code : Tout sélectionner

pkgname=ivy-c
pkgver=3.9.2
pkgrel=1
pkgdesc="ivy-c Library"
arch=('i686' 'x86_64')
url="http://www.eei.cena.fr/products/ivy/download/source.html"
license=('GPL3')
depends=('tcl')
makedepends=('cmake')
source=("http://www.eei.cena.fr/products/ivy/download/packages/${pkgname}-${pkgver}.tar.gz")
md5sums=('c105e1f42ad2020e6b7ae83709b073e7')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}/src"
  sed -i 's|lib$(PERHAPS64)|lib|' Makefile
  sed -i 's|mkdirhier|mkdir -p|g' Makefile
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}/src"
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}/src"
  make PREFIX="/usr" DESTDIR="${pkgdir}" install
}

[gael]

ça fonctionne merci beaucoup