[conky] support xmms2 (résolu)
[conky] support xmms2 (résolu)
Bonjour à tous,
Je suis sur raspberry pi 3B, architecture armv7 donc.
J'essaye de compiler conky à partir des sources récupérées sur github pour avoir le support de xmms2 qui est absent du paquet obtenu avec pacman (conky version 1.11.5) mais je bute sur ce problème :
Dans le config.h.in j'ai bien la ligne :
#cmakedefine BUILD_XMMS2 1
mais après un cmake, j'obtiens dans le config.h :
/* #undef BUILD_XMMS2 */
Et si je modifie ce fichier directement pour avoir :
#define BUILD_XMMS2 1
bien sûr, le make s'arrète avec l'erreur :
fatal error: xmmsclient/xmmsclient.h: No such file or directory
32 | #include <xmmsclient/xmmsclient.h>
J'aurais besoin de vos lumières
Merci d'avance !
Je suis sur raspberry pi 3B, architecture armv7 donc.
J'essaye de compiler conky à partir des sources récupérées sur github pour avoir le support de xmms2 qui est absent du paquet obtenu avec pacman (conky version 1.11.5) mais je bute sur ce problème :
Dans le config.h.in j'ai bien la ligne :
#cmakedefine BUILD_XMMS2 1
mais après un cmake, j'obtiens dans le config.h :
/* #undef BUILD_XMMS2 */
Et si je modifie ce fichier directement pour avoir :
#define BUILD_XMMS2 1
bien sûr, le make s'arrète avec l'erreur :
fatal error: xmmsclient/xmmsclient.h: No such file or directory
32 | #include <xmmsclient/xmmsclient.h>
J'aurais besoin de vos lumières
Merci d'avance !
Dernière modification par Uzo67 le ven. 22 mai 2020, 16:45, modifié 1 fois.
- benjarobin
- Maître du Kyudo
- Messages : 17235
- Inscription : sam. 30 mai 2009, 15:48
- Localisation : Lyon
Re: conky et support xmms2
Utilise ce PKGBUILD
Code : Tout sélectionner
# Maintainer: Gaetan Bisson <bisson@archlinux.org>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: James Rayner <james@archlinux.org>
# Contributor: Partha Chowdhury <kira.laucas@gmail.com>
pkgname=conky
pkgver=1.11.5
pkgrel=3
pkgdesc='Lightweight system monitor for X'
url='https://github.com/brndnmtthws/conky'
license=('BSD' 'GPL')
arch=('x86_64')
makedepends=('cmake' 'docbook2x' 'docbook-xsl' 'man-db' 'git')
depends=('glib2' 'lua' 'wireless_tools' 'libxdamage' 'libxinerama' 'libxft'
'imlib2' 'libxml2' 'libpulse' 'libxnvctrl' 'xmms2')
source=("https://github.com/brndnmtthws/conky/archive/v${pkgver}.tar.gz")
sha256sums=('4cefdd92219a90934c28297e4ac7448a3f69d6aeec5d48c5763b23f6b214ef13')
options=('!strip' 'debug')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
cmake \
-D CMAKE_BUILD_TYPE=Release \
-D MAINTAINER_MODE=ON \
-D BUILD_DOCS=ON \
-D BUILD_WLAN=ON \
-D BUILD_XDBE=ON \
-D BUILD_XSHAPE=ON \
-D BUILD_IMLIB2=ON \
-D BUILD_CURL=ON \
-D BUILD_RSS=ON \
-D BUILD_NVIDIA=ON \
-D BUILD_WEATHER_METAR=ON \
-D BUILD_PULSEAUDIO=ON \
-D BUILD_JOURNAL=ON \
-D BUILD_XMMS2=ON \
-D CMAKE_INSTALL_PREFIX=/usr \
.
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm644 extras/vim/syntax/conkyrc.vim "${pkgdir}"/usr/share/vim/vimfiles/syntax/conkyrc.vim
install -Dm644 extras/vim/ftdetect/conkyrc.vim "${pkgdir}"/usr/share/vim/vimfiles/ftdetect/conkyrc.vim
}
Zsh | KDE | PC fixe : core i7, carte nvidia
Titre d'un sujet : [Thème] Sujet (état) / Règles du forum
Titre d'un sujet : [Thème] Sujet (état) / Règles du forum
Re: conky et support xmms2
Merci benjarobin. Mais après avoir modifié le pkgbuild pour mettre
arch=('armv7h')
et avoir enlevé la dépendance
libxnvctrl
car je n'ai pas de carte nv et je ne peux installer ce paquet, je me retrouve avec tout de même l'erreur liée à l'absence de libxnvctrl :
CMake Error at cmake/ConkyPlatformChecks.cmake:456 (message):
Unable to find XNVCtrl library
Donc je suis de nouveau coincé...
arch=('armv7h')
et avoir enlevé la dépendance
libxnvctrl
car je n'ai pas de carte nv et je ne peux installer ce paquet, je me retrouve avec tout de même l'erreur liée à l'absence de libxnvctrl :
CMake Error at cmake/ConkyPlatformChecks.cmake:456 (message):
Unable to find XNVCtrl library
Donc je suis de nouveau coincé...
- benjarobin
- Maître du Kyudo
- Messages : 17235
- Inscription : sam. 30 mai 2009, 15:48
- Localisation : Lyon
Re: conky et support xmms2
Essaye ceci
Code : Tout sélectionner
pkgname=conky
pkgver=1.11.5
pkgrel=3
pkgdesc='Lightweight system monitor for X'
url='https://github.com/brndnmtthws/conky'
license=('BSD' 'GPL')
arch=('armv7h')
makedepends=('cmake' 'docbook2x' 'docbook-xsl' 'man-db' 'git')
depends=('glib2' 'lua' 'wireless_tools' 'libxdamage' 'libxinerama' 'libxft'
'imlib2' 'libxml2' 'libpulse' 'xmms2')
source=("https://github.com/brndnmtthws/conky/archive/v${pkgver}.tar.gz")
sha256sums=('4cefdd92219a90934c28297e4ac7448a3f69d6aeec5d48c5763b23f6b214ef13')
options=('!strip' 'debug')
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
cmake \
-D CMAKE_BUILD_TYPE=Release \
-D MAINTAINER_MODE=ON \
-D BUILD_DOCS=ON \
-D BUILD_WLAN=ON \
-D BUILD_XDBE=ON \
-D BUILD_XSHAPE=ON \
-D BUILD_IMLIB2=ON \
-D BUILD_CURL=ON \
-D BUILD_RSS=ON \
-D BUILD_WEATHER_METAR=ON \
-D BUILD_PULSEAUDIO=ON \
-D BUILD_JOURNAL=ON \
-D BUILD_XMMS2=ON \
-D CMAKE_INSTALL_PREFIX=/usr \
.
make
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm644 extras/vim/syntax/conkyrc.vim "${pkgdir}"/usr/share/vim/vimfiles/syntax/conkyrc.vim
install -Dm644 extras/vim/ftdetect/conkyrc.vim "${pkgdir}"/usr/share/vim/vimfiles/ftdetect/conkyrc.vim
}
Zsh | KDE | PC fixe : core i7, carte nvidia
Titre d'un sujet : [Thème] Sujet (état) / Règles du forum
Titre d'un sujet : [Thème] Sujet (état) / Règles du forum
Re: conky et support xmms2
C'est parfait ! Merci beaucoup