[AUR] Erreur dans package() (résolu)

Mise à jour / Création /debug de paquetages
Répondre
@rché0
Daikyu
Messages : 90
Inscription : jeu. 09 sept. 2021, 20:57

[AUR] Erreur dans package() (résolu)

Message par @rché0 »

Bonjour,

après de nombreuses tentatives qui ont toutes échouées, je m'en remet à vous.
Je veux poster un paquet sur l'AUR mais je bloque sur le PKGBUILD qui devrait logiquement être plutôt basique :oops:

C'est un paquet destiné à fortune-mod, voici le PKGBUILD :

Code : Tout sélectionner

# Maintainer: Th30
pkgname=fortune-mod-wisdom-fr
pkgver=1.1
pkgrel=1
pkgdesc="Fortune cookies: Wisdom quotes in French"
arch=('any')
url="https://github.com/Bundy01/fortune-mod-wisdom-fr"
license=('GPL3')
depends=('fortune-mod')
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/${pkgver}.tar.gz")
sha256sums=('cb3a631f51dbe1ce5adc19179548fecdfe5aaf17ecf220750cacec6f831e5ef4')

package()
{
	cd "${pkgname}-${pkgver}"
	install -Dm644 Asie{,.dat} "${pkgdir}/usr/share/fortune/wisdom-fr"
	install -Dm644 Occident{,.dat} "${pkgdir}/usr/share/fortune/wisdom-fr"
	install -Dm644 RastAfrica{,.dat} "${pkgdir}/usr/share/fortune/wisdom-fr"
}
Ça ne passe pas dans le package()
Dernière modification par @rché0 le ven. 02 juin 2023, 01:17, modifié 1 fois.
@rché0
Daikyu
Messages : 90
Inscription : jeu. 09 sept. 2021, 20:57

Re: [AUR] Erreur dans package ()

Message par @rché0 »

J'ai trouvé, il suffisait de rajouter cette ligne avant les 'install':

Code : Tout sélectionner

mkdir -pm755 "${pkgdir}/usr/share/fortune/wisdom-fr"
C'est mon tout premier paquet pour l'AUR, je me suis inspiré de ceux existant et il n'y avais pas cette ligne sur les autres PKGBUILDs.
Avez-vous une explication, pour que je comprenne ce qui c'est passée ?
Avatar de l’utilisateur
benjarobin
Maître du Kyudo
Messages : 17180
Inscription : sam. 30 mai 2009, 15:48
Localisation : Lyon

Re: [AUR] Erreur dans package() (résolu)

Message par benjarobin »

Hum tes 3 commandes install sont fausses. Soit tu créer le dossier avant puis tu utilises install sans l'option -D.
Soit tu utilises l'option -D puis tu indiques à la fin du chemin (de destination) le nom du fichier (qui est donc indiqué 2 fois)
Zsh | KDE | PC fixe : core i7, carte nvidia
Titre d'un sujet : [Thème] Sujet (état) / Règles du forum
@rché0
Daikyu
Messages : 90
Inscription : jeu. 09 sept. 2021, 20:57

Re: [AUR] Erreur dans package() (résolu)

Message par @rché0 »

Salut,

ok, je vais supprimer les options -D.
Peux-tu me dire pourquoi ça ne passait pas avec le PKGBUILD du début (avec -D et sans mkdir) ?
Avatar de l’utilisateur
benjarobin
Maître du Kyudo
Messages : 17180
Inscription : sam. 30 mai 2009, 15:48
Localisation : Lyon

Re: [AUR] Erreur dans package() (résolu)

Message par benjarobin »

Voir le man de install, tu comprendras ce que tu faisais...
Zsh | KDE | PC fixe : core i7, carte nvidia
Titre d'un sujet : [Thème] Sujet (état) / Règles du forum
@rché0
Daikyu
Messages : 90
Inscription : jeu. 09 sept. 2021, 20:57

Re: [AUR] Erreur dans package() (résolu)

Message par @rché0 »

Ok,

il aurait fallu que j'utilise l'option -d à la place de -D.
Ou que je fasse install -Dm644 Asie{,.dat} "${pkgdir}/usr/share/fortune/wisdom-fr/Asie{,.dat}"

Une autre question en rapport au PKGBUILD, dois-je installer la license ? Je pose la question car certains fichiers le font et d'autres non; que se soit sur l'AUR ou avec des paquets officiels.
Avatar de l’utilisateur
benjarobin
Maître du Kyudo
Messages : 17180
Inscription : sam. 30 mai 2009, 15:48
Localisation : Lyon

Re: [AUR] Erreur dans package() (résolu)

Message par benjarobin »

En théorie je crois que tu devrais, tout dépend si tu veux créer un paquet sur AUR ou juste pour toi.
Et non l'option -d ne fait pas ce que tu indiques, voir le man de install (cela créer juste des dossiers, aucune copie de fichier) !
Zsh | KDE | PC fixe : core i7, carte nvidia
Titre d'un sujet : [Thème] Sujet (état) / Règles du forum
@rché0
Daikyu
Messages : 90
Inscription : jeu. 09 sept. 2021, 20:57

Re: [AUR] Erreur dans package() (résolu)

Message par @rché0 »

Je l'ai lu lui ainsi que le help :/ ça ne m'a pas plus arrangé (pas taper).
C'est pour l'AUR, donc je vais la rajouter. La commande dans mon dernier post est-elle correcte ?
Avatar de l’utilisateur
benjarobin
Maître du Kyudo
Messages : 17180
Inscription : sam. 30 mai 2009, 15:48
Localisation : Lyon

Re: [AUR] Erreur dans package() (résolu)

Message par benjarobin »

Non elle n'est pas correcte.
Ceci l'est :

Code : Tout sélectionner

install -Dm644 Asie "${pkgdir}/usr/share/fortune/wisdom-fr/Asie"
install -Dm644 Asie.dat "${pkgdir}/usr/share/fortune/wisdom-fr/Asie.dat"
Ou ceci

Code : Tout sélectionner

install -dm755 "${pkgdir}/usr/share/fortune/wisdom-fr"
install -m644 Asie{,.dat} "${pkgdir}/usr/share/fortune/wisdom-fr"
Zsh | KDE | PC fixe : core i7, carte nvidia
Titre d'un sujet : [Thème] Sujet (état) / Règles du forum
@rché0
Daikyu
Messages : 90
Inscription : jeu. 09 sept. 2021, 20:57

Re: [AUR] Erreur dans package() (résolu)

Message par @rché0 »

Merci pour ton aide précieuse. Voici le PKGBUILD final

Code : Tout sélectionner

# Maintainer: Th30
pkgname=fortune-mod-wisdom-fr
pkgver=1.1
pkgrel=4
pkgdesc="Fortune cookies: Wisdom quotes in French"
arch=('any')
url="https://github.com/Bundy01/fortune-mod-wisdom-fr"
license=('GPL3')
depends=('fortune-mod')
source=("${pkgname}-${pkgver}.tar.gz::${url}/archive/refs/tags/${pkgver}.tar.gz")
sha256sums=('cb3a631f51dbe1ce5adc19179548fecdfe5aaf17ecf220750cacec6f831e5ef4')

package()
{
    cd "${pkgname}-${pkgver}"
    install -dm755 "${pkgdir}/usr/share/fortune/wisdom-fr"
    install -m644 Asie{,.dat} "${pkgdir}/usr/share/fortune/wisdom-fr"
    install -m644 Occident{,.dat} "${pkgdir}/usr/share/fortune/wisdom-fr"
    install -m644 RastAfrica{,.dat} "${pkgdir}/usr/share/fortune/wisdom-fr"
    install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
Avatar de l’utilisateur
benjarobin
Maître du Kyudo
Messages : 17180
Inscription : sam. 30 mai 2009, 15:48
Localisation : Lyon

Re: [AUR] Erreur dans package() (résolu)

Message par benjarobin »

Hum, non... J'avais édité mon dernier message, j'avais fait une erreur de copier-coller. Tu n'as pas du voir l'édition du message.
Pourquoi ne testes tu pas ton PKGBUILD...
Bref, j'ai édité ton message et corrigé le PKGBUILD
Zsh | KDE | PC fixe : core i7, carte nvidia
Titre d'un sujet : [Thème] Sujet (état) / Règles du forum
Répondre