Archlinux.fr [Forums]

Bonjour,

J'ai eu la chance d'avoir une imprimante Epson xp-205 207 série.

Évidement aucun packages dans le dépot officiel et non plus sur AUR pour la prise en charge de cette imprimante.

J'ai donc décidé de me rendre sur le site officiel et de télécharger le source en rpm http://download.ebz.epson.net/dsc/searc ... archModule
http://download.ebz.epson.net/dsc/du/02 ... 76fd689dd0
J'ai extrait et j'ai lu le INSTALL qui indique de faire un ./configure avant le make et make install.

Quand je lance le ./configure j'ai une erreur de path "

Code : Tout sélectionner

configure: error: *** '--prefix=/PATH' missing, please specify a prefix PATH ***

"
Voici le pastebin ./configure http://pastebin.archlinux.fr/451744

Donc je ne sais pas quoi faire car il me semble que Arch respecte la norme POSX ?
Après en fouillant dans config.log on trouve cette erreur

Code : Tout sélectionner

onftest.c:10:28: fatal error: ac_nonexistent.h: No such file or directory

:
Voici le pastebin de config.log http://pastebin.archlinux.fr/451758

J'ai également lu (http://lists.gnu.org/archive/html/autoc ... 00011.html) que cette erreur était souvent du aux différents prefix -all-static qu'il faut enlever mais j'en ai pas (en il me semble) et je crois qu'il fallait ajouter un env de variable à ./config --enable-static=no.

En espérant avoir été assez clair pour ce premier sujet que je poste !
Merci d'avoir lu !

Je te conseil de t'inspirer de ce paquet epson-inkjet-printer-201112w

Salut benjarobin,
Tu veux dire que le mieux c'est de reprendre avec un diff le Makeinstall et le config du paquet epson-inkjet-printer-201112w ?
Merci !

Non, voici le PKGBUILD (compile chez moi) une fois modifié

Code : Tout sélectionner

pkgname=epson-inkjet-printer-201202w
_pkgname_filter=epson-inkjet-printer-filter
pkgver=1.0.0
pkgrel=1
pkgdesc="Epson printer driver (XP-102 103 Series, XP-202 203 206 Series, XP-205 207 Series, XP-30 33 Series)"
arch=('i686' 'x86_64')
url="http://avasys.jp/eng/linux_driver/download/lsb/epson-inkjet/escp/"
license=('GPL' 'LGPL' 'custom:AVASYS Public Licence')
depends=('cups')
makedepends=('rpmextract' 'libtool' 'make' 'automake' 'autoconf')
source=(http://a1227.g.akamai.net/f/1227/40484/1d/download.ebz.epson.net/dsc/f/01/00/01/77/09/d9c270238d35e885c89b4686665b383be8308fb8/$pkgname-$pkgver-1lsb3.2.src.rpm)

build() {
  cd "$startdir/src"
  rpmextract.sh $pkgname-$pkgver-1lsb3.2.src.rpm
  tar xzf $pkgname-$pkgver.tar.gz
  FILTER_FILE=`ls $_pkgname_filter*.tar.gz`
  tar xzf $FILTER_FILE

  cd "${FILTER_FILE%.tar.gz}"
  aclocal
  libtoolize
  chmod +x configure
  # if you have runtime problems: add "--enable-debug" and look into /tmp/epson-inkjet-printer-filter.txt
  ./configure LDFLAGS="$LDFLAGS -Wl,--no-as-needed" --prefix=/opt/$pkgname
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  install -d "$pkgdir/opt/$pkgname/"
  if [ "$CARCH" = "x86_64" ]; then
     cp -r lib64 "$pkgdir/opt/$pkgname/"
  else
     cp -r lib "$pkgdir/opt/$pkgname/"
  fi
  cp -r resource "$pkgdir/opt/$pkgname/"

  if [ -e "watermark" ]; then
      cp -r watermark "$pkgdir/opt/$pkgname/"
  fi
  install -d "$pkgdir/usr/share/cups/model/$pkgname"
  install -m 644 ppds/* "$pkgdir/usr/share/cups/model/$pkgname"

  cd "$srcdir"
  FILTER_FILE=`ls $_pkgname_filter*.tar.gz`
  cd "${FILTER_FILE%.tar.gz}"
  install -d "$pkgdir/opt/$pkgname/cups/lib/filter/"
  install -m 755 src/epson_inkjet_printer_filter "$pkgdir/opt/$pkgname/cups/lib/filter/epson_inkjet_printer_filter"
}
sha256sums=('cd7815690c241d02fe4a6941932d5127d39f9c2f2f493267188bc9a0d517f18c')

Poowah! Merci c'est trop bête ça marche vraiment bien Merci !

Alors en effet si on créer le PKGBUILD avec le code de benjarobin on a fait un makepkg et un pacman -U et ça marche.

Pour iscan ça devrait marcher aussi j'imagine je vais voir ça !

Faut il que je le rajoute dans AUR avec les bonnes sources pour les autres ?

A toi de voir si tu te sens de le maintenir

Après je ne fait qu'adapter, ce n'est pas moi qui est fournit le gros du travail.

Archlinux.fr [Forums]

[Printer] Filtres manquant Epson XP-205 207 [Résolu]

[Printer] Filtres manquant Epson XP-205 207 [Résolu]

Re: [Printer] Filtres manquant Epson XP-205 207 [En cours]

Re: [Printer] Filtres manquant Epson XP-205 207 [En cours]

Re: [Printer] Filtres manquant Epson XP-205 207 [En cours]

Re: [Printer] Filtres manquant Epson XP-205 207 [Résolu]

Re: [Printer] Filtres manquant Epson XP-205 207 [En cours]