Archlinux.fr [Forums]

Code : Tout sélectionner

pkgname=deal-ii
_realname=deal.II
pkgver=8.0.0
pkgrel=2
pkgdesc="A Finite Element Differential Equations Analysis Library"
arch=("i686" "x86_64")
url="http://www.dealii.org/"
license=('LGPL')
depends=()
makedepends=('cmake' 'make')
install=deal-ii.install
source=(https://dealii.googlecode.com/files/${_realname}-$pkgver.tar.gz)
md5sums=('6d44304e9ec7697203e944321a30f343')

build() {
  cd "${srcdir}/${_realname}"

  rm -rf "${srcdir}/build"
  mkdir "${srcdir}/build"
  cd "${srcdir}/build"

  cmake -DCMAKE_INSTALL_PREFIX=/usr/ ../${_realname}

  make
}

package() {
  cd "${srcdir}/build"
  make DESTDIR="${pkgdir}" install

  # doc
  mkdir -p ${pkgdir}/usr/share/doc/${_realname}
  cp -r ${srcdir}/${_realname}/doc ${pkgdir}/usr/share/doc/${_realname}

  # examples
  cp -r ${srcdir}/${_realname}/examples ${pkgdir}/usr/share/doc/${_realname}

  install -D -m644 ${srcdir}/${_realname}/LICENSE "${pkgdir}/usr/share/licenses/${_realname}/LICENSE"
}