Page 1 sur 1
[Repo ArchLinuxFR] youtube-dl
Publié : dim. 13 déc. 2015, 19:33
par Case_Of
Bonjour,
Le paquet youtube-dl sur les dépôts officiels n'étant pas très souvent mis à jour comparé aux versions sorties par les développeurs du programme, j'ai pensé qu'il pouvait être judicieux de proposer sur un dépôt non officiel un paquet plus souvent mis à jour. De mon côté, je me suis déjà inspiré du PKGBUILD du dépôt officiel pour faire mon paquet, le voici :
Code : Tout sélectionner
# $Id$
# Maintainer: Case_Of
pkgname=youtube-dl
pkgver=2015.12.13
pkgrel=1
pkgdesc="A small command-line program to download videos from YouTube.com and a few more sites"
arch=('any')
url="http://rg3.github.io/youtube-dl/"
license=('custom')
depends=('python' 'python-setuptools')
optdepends=('ffmpeg: for video post-processing'
'rtmpdump: for rtmp streams support'
'atomicparsley: for embedding thumbnails into m4a files')
source=(http://youtube-dl.org/downloads/${pkgver}/${pkgname}-${pkgver}.tar.gz)
sha1sums=('d008460bc72091a62b8de45bad2e88d049d8a84b')
prepare() {
cd ${pkgname}
sed -i 's|etc/bash_completion.d|share/bash-completion/completions|' setup.py
sed -i 's|etc/fish/completions|share/fish/completions|' setup.py
}
package() {
cd ${pkgname}
python setup.py install --root="${pkgdir}/" --optimize=1
mv "${pkgdir}/usr/share/bash-completion/completions/youtube-dl.bash-completion" \
"${pkgdir}/usr/share/bash-completion/completions/youtube-dl"
install -Dm644 youtube-dl.zsh "${pkgdir}/usr/share/zsh/site-functions/_youtube-dl"
install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
Je le soumet donc pour vérification avant de proposer éventuellement le paquet sur le dépôt ArchLinuxFR.
Toute remarque est également la bienvenue.
PS: Si je ne choisis pas le paquet AUR/youtube-dl-git c'est parce qu'il ne récupère pas la dernière version stable mais le dernier commit potentiellement instable. Et je n'utilise pas pip car je ne veux pas accumuler les problèmes.
Re: [Repo ArchLinuxFR] youtube-dl
Publié : dim. 13 déc. 2015, 20:34
par waitnsea
Bonsoir,
Remarque de départ, le paquet étant dans le dépôt Community, tu dois lui donner un suffixe avant de le proposer dans AUR, non ?
Usage sinon quotidien, au moins pluri-hebdomadaire pour moi, je regarde avec intérêt...
Re: [Repo ArchLinuxFR] youtube-dl
Publié : dim. 13 déc. 2015, 21:46
par Case_Of
nheir avec qui j'ai discuté sur le channel irc #archlinux-fr sur freenode propose ce PKGBUILD :
Code : Tout sélectionner
pkgname=youtube-dl-release
pkgver=2015.12.13
pkgrel=1
pkgdesc='A small command-line program to download videos from YouTube.com and a few more sites'
url="http://rg3.github.io/youtube-dl"
arch=('any')
license=('custom')
depends=('python' 'python-setuptools')
makedepends=('git')
optdepends=('ffmpeg: for video post-processing')
provides=('youtube-dl')
conflicts=('youtube-dl')
source=('git://github.com/rg3/youtube-dl.git')
md5sums=('SKIP')
pkgver() {
cd youtube-dl
git describe --long | cut -f1 -d-
}
prepare() {
cd youtube-dl
sed -i 's|etc/bash_completion.d|share/bash-completion/completions|' setup.py
sed -i ':etc/fish/completions:d' setup.py
git checkout $pkgver
}
package() {
cd youtube-dl
python devscripts/bash-completion.py
python setup.py install --root="$pkgdir" --optimize=1
mv "$pkgdir"/usr/share/bash-completion/completions/youtube-dl.bash-completion \
"$pkgdir"/usr/share/bash-completion/completions/youtube-dl
install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/"$pkgname"/LICENSE
}
Lequel préférez vous ?
Re: [Repo ArchLinuxFR] youtube-dl
Publié : dim. 13 déc. 2015, 22:18
par benjarobin
Bonjour, je ne comprend pas bien le but de ce PKGBUILD... Il y a déjà youtube-dl-git qui est identique au PKGBUILD proposé...
Sinon il est strictement interdit de proposer un paquet sur AUR avec le même nom qu'un paquet des dépôts officiels
Voici une version fonctionnelle faisant ce que tu veux faire et aussi assez rapide (on n'est pas obligé de télécharger tout le git )
Tu peux le proposer sur AUR, il se met à jour "tout seul" et récupère uniquement les release stable.
Après c'est à l'utilisateur de lancer manuellement la mise à jour du paquet, ce dernier ne sera pas proposé par yaourt par exemple.
Code : Tout sélectionner
pkgname=youtube-dl-release
pkgver=2015.12.13
pkgrel=1
pkgdesc='A small command-line program to download videos from YouTube.com and a few more sites'
url="http://rg3.github.io/youtube-dl"
arch=('any')
license=('custom')
depends=('python' 'python-setuptools')
makedepends=('git')
optdepends=('ffmpeg: for video post-processing')
provides=('youtube-dl')
conflicts=('youtube-dl')
_pkgver_found=$(git ls-remote -t https://github.com/rg3/youtube-dl.git | grep -Eo "201[56]\.[0-9]+\.[0-9]+" | sort | tail -1)
source=("https://github.com/rg3/youtube-dl/archive/${_pkgver_found}.zip")
md5sums=('SKIP')
pkgver() {
echo $_pkgver_found
}
prepare() {
cd youtube-dl-$pkgver
sed -i 's|etc/bash_completion.d|share/bash-completion/completions|' setup.py
sed -i ':etc/fish/completions:d' setup.py
}
package() {
cd youtube-dl-$pkgver
python devscripts/bash-completion.py
python setup.py install --root="$pkgdir" --optimize=1
mv "$pkgdir"/usr/share/bash-completion/completions/youtube-dl.bash-completion \
"$pkgdir"/usr/share/bash-completion/completions/youtube-dl
install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/"$pkgname"/LICENSE
}