Archlinux.fr [Forums]

Le paquet community/youtube-dl étant insuffisamment régulièrement mis à jour ayant pour conséquence d'être souvent cassé et le paquet aur/youtube-dl-git se basant sur le dernier commit étant du coup instable, je propose un juste milieu de mon point de vue que chacun jugera comme il l'entend.

Voilà le PKGBUILD de youtube-dl dont je me sers pour maintenir le paquet sur mes machines :

Code : Tout sélectionner

pkgname=youtube-dl
pkgver="$(curl -s 'http://youtube-dl.org/latest/version')"
pkgrel=1
pkgdesc="A small command-line program to download videos from YouTube.com and a few more sites"
arch=('any')
url="http://rg3.github.io/youtube-dl/"
license=('custom')
depends=('python' 'python-setuptools')
optdepends=('ffmpeg: for video post-processing'
            'rtmpdump: for rtmp streams support'
	    'atomicparsley: for embedding thumbnails into m4a files')
source=(http://youtube-dl.org/downloads/${pkgver}/${pkgname}-${pkgver}.tar.gz
        http://youtube-dl.org/downloads/${pkgver}/${pkgname}-${pkgver}.tar.gz.sig)
sha512sums=("$(curl -L -s 'http://youtube-dl.org/latest/SHA2-512SUMS' |  sed -n 's/\([0-9a-f]\{128\}\) .*\.tar\.gz/\1/p')"
          'SKIP')
validpgpkeys=('7D33D762FD6C35130481347FDB4B54CBA4826A18'
        '428DF5D63EF07494BB455AC0EBF01804BCF05F6B'
        'ED7F5BF46B3BBED81C87368E2C393E0F18A9236D')

prepare() {
  cd ${pkgname}
  sed -i 's|etc/bash_completion.d|share/bash-completion/completions|' setup.py
  sed -i 's|etc/fish/completions|share/fish/completions|' setup.py
}

package() {
  cd ${pkgname}
  python setup.py install --root="${pkgdir}/" --optimize=1
  mv "${pkgdir}/usr/share/bash-completion/completions/youtube-dl.bash-completion" \
     "${pkgdir}/usr/share/bash-completion/completions/youtube-dl"
  install -Dm644 youtube-dl.zsh "${pkgdir}/usr/share/zsh/site-functions/_youtube-dl"
  install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

N'hésitez pas à poser vos questions et donner votre avis. Et à proposer éventuellement vos PKGBUILDs.
Vous pouvez utiliser mon PKGBUILD comme il vous plaira sur vos machines ou à le partager.

Il y a juste par rapport à pkgver et sha512sums que j'ai une remarque à faire. Normalement, pkgver devrait contenir directement la valeur.
Ensuite, pour sha512sums, la règle est simple : pour les sommes de contrôle c'est '' si le fichier dans source est versionné, et 'SKIP' pour tout ce qui est sources VCS et signatures.

Code : Tout sélectionner

pkgver=2016.06.14
...
source=(http://youtube-dl.org/downloads/${pkgver}/${pkgname}-${pkgver}.tar.gz{,.sig})
sha512sums=(''
          'SKIP')

S'il y a un '' dans sha512sums, il faut exécuter la commande updpkgsums dans le répertoire qui contient le PKGBUILD.

Archlinux.fr [Forums]

[PKG] youtube-dl

[PKG] youtube-dl

Re: [PKG] youtube-dl